1 files changed, 71 insertions, 0 deletions
diff --git a/lib/MaildirIndexer/Parser.pm6 b/lib/MaildirIndexer/Parser.pm6
new file mode 100644
index 0000000..90b3678
--- /dev/null
+++ b/lib/MaildirIndexer/Parser.pm6
@@ -0,0 +1,71 @@
+use v6.d.PREVIEW;
+unit module MaildirIndexer::Parser;
+
+my @separators = (
+    "\x0a\x0d\x0a\x0d",
+    "\x0d\x0a\x0d\x0a",
+    "\x0a\x0a",
+    "\x0d\x0d",
+);
+
+grammar Message {
+    regex TOP {
+        <headers>
+        <separator>
+        <body>
+    }
+
+    token newline { [\x0d\x0a] | [\x0a\x0d] | \x0a | \x0d }
+    token separator { @separators }
+
+    token body { .* }
+    regex headers {
+        <header>+ % <newline>
+    }
+    regex header {
+        <name> \: \h* <value>
+                 || <junk>
+    }
+    token name {
+        <-[:\s]>+
+    }
+    regex value {
+        <line>+ % [<newline> \h+]
+    }
+    token line { \N* }
+    token junk { \N+ }
+}
+
+class Message-actions {
+    method TOP($/) {
+        make %( headers => $/<headers>.made, body => $/<body>.Str );
+    }
+    method headers($/) {
+        make %( |$/<header>».made );
+    }
+    method header($/) {
+        make $/<junk> ?? () !! ( $/<name>.Str => $/<value>.made );
+    }
+    method value($/) {
+        make $/<line>.join(' ')
+    }
+}
+
+multi parse-email(IO::Path $p) is export {
+    return parse-email($p.slurp(:enc<utf8-c8>));
+}
+multi parse-email(IO::Path $p, :$headers-only!) is export {
+    return parse-email(
+        $p.lines(
+            :enc<utf8-c8>,
+            :nl-in(@separators),
+            :!chomp,
+        )[0],
+    );
+}
+multi parse-email(Str $email-str) is export {
+    with Message.parse($email-str,:actions(Message-actions.new)) {
+        return .made;
+    }
+    return Nil;
+}