lib/Data/MultiValued/AttributeAccessors.pm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186

package Data::MultiValued::AttributeAccessors; 
{
  $Data::MultiValued::AttributeAccessors::VERSION = '0.0.6_1';
}
{
  $Data::MultiValued::AttributeAccessors::DIST = 'Data-MultiValued';
}
use strict;
use warnings;
use base 'Moose::Meta::Method::Accessor';
use Carp 'confess';
 
# ABSTRACT: method meta-class for multi-valued attribute accessors 
 
 
sub _instance_is_inlinable { 0 }
 
 
sub _generate_accessor_method {
    my $self = shift;
    my $attr = $self->associated_attribute;
 
    return sub {
        if (@_ >= 2) {
            $attr->set_multi_value($_[0], {}, $_[1]);
        }
        $attr->get_multi_value($_[0], {});
    }
}
 
sub _generate_reader_method {
    my $self = shift;
    my $attr = $self->associated_attribute;
 
    return sub {
        confess "Cannot assign a value to a read-only accessor"
            if @_ > 1;
        $attr->get_multi_value($_[0], {});
    };
}
 
sub _generate_writer_method {
    my $self = shift;
    my $attr = $self->associated_attribute;
 
    return sub {
        $attr->set_multi_value($_[0], {}, $_[1]);
    };
}
 
sub _generate_predicate_method {
    my $self = shift;
    my $attr = $self->associated_attribute;
 
    return sub {
        $attr->has_multi_value($_[0], {})
    };
}
 
sub _generate_clearer_method {
    my $self = shift;
    my $attr = $self->associated_attribute;
 
    return sub {
        $attr->clear_multi_value($_[0], {})
    };
}
 
 
sub _generate_multi_accessor_method {
    my $self = shift;
    my $attr = $self->associated_attribute;
 
    return sub {
        if (@_ >= 3) {
            $attr->set_multi_value($_[0], $_[1], $_[2]);
        }
        $attr->get_multi_value($_[0],$_[1]);
    }
}
 
sub _generate_multi_reader_method {
    my $self = shift;
    my $attr = $self->associated_attribute;
 
    return sub {
        confess "Cannot assign a value to a read-only accessor"
            if @_ > 2;
        $attr->get_multi_value($_[0],$_[1]);
    };
}
 
sub _generate_multi_writer_method {
    my $self = shift;
    my $attr = $self->associated_attribute;
 
    return sub {
        $attr->set_multi_value($_[0], $_[1], $_[2]);
    };
}
 
sub _generate_multi_predicate_method {
    my $self = shift;
    my $attr = $self->associated_attribute;
 
    return sub {
        $attr->has_multi_value($_[0],$_[1])
    };
}
 
sub _generate_multi_clearer_method {
    my $self = shift;
    my $attr = $self->associated_attribute;
 
    return sub {
        $attr->clear_multi_value($_[0],$_[1])
    };
}
 
1;
 
__END__
=pod
 
=encoding utf-8
 
=head1 NAME
 
Data::MultiValued::AttributeAccessors - method meta-class for multi-valued attribute accessors
 
=head1 VERSION
 
version 0.0.6_1
 
=head1 DESCRIPTION
 
Subclass of L<Moose::Meta::Method::Accessor>, generates non-inlined
(patches welcome) accessors for multi-valued attributes.
 
=head1 METHODS
 
=head2 C<_instance_is_inlinable>
 
Returns C<0> to prevent attempts to inline the accessor methods.
 
=head2 C<_generate_accessor_method>
 
=head2 C<_generate_reader_method>
 
=head2 C<_generate_writer_method>
 
=head2 C<_generate_predicate_method>
 
=head2 C<_generate_clearer_method>
 
Delegate to C<set_multi_value>, C<get_multi_value>,
C<has_multi_value>, C<clear_multi_value>, passing empty options
(i.e. no tags, no ranges).
 
=head2 C<_generate_multi_accessor_method>
 
=head2 C<_generate_multi_reader_method>
 
=head2 C<_generate_multi_writer_method>
 
=head2 C<_generate_multi_predicate_method>
 
=head2 C<_generate_multi_clearer_method>
 
Delegate to C<set_multi_value>, C<get_multi_value>,
C<has_multi_value>, C<clear_multi_value>, passing C<$_[1]> as options
and C<$_[2]> as values.
 
=head1 AUTHOR
 
Gianni Ceccarelli <dakkar@thenautilus.net>
 
=head1 COPYRIGHT AND LICENSE
 
This software is copyright (c) 2011 by Net-a-Porter.com.
 
This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.
 
=cut