From 0d41052d7eb2d7e45d839b5e042bfc5d796f9750 Mon Sep 17 00:00:00 2001
From: dakkar <dakkar@thenautilus.net>
Date: Fri, 27 Mar 2020 13:16:38 +0000
Subject: PrusaSlicer 2.2.0 and dependencies

there's apparently lots of new dependencies, or maybe newer versions
are needed. I've added them to the PrusaSlicer ebuild, and added the
ebuilds for them.

Seems to work
---
 dev-libs/c-blosc/c-blosc-1.17.1.ebuild | 51 ++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 dev-libs/c-blosc/c-blosc-1.17.1.ebuild

(limited to 'dev-libs/c-blosc/c-blosc-1.17.1.ebuild')

diff --git a/dev-libs/c-blosc/c-blosc-1.17.1.ebuild b/dev-libs/c-blosc/c-blosc-1.17.1.ebuild
new file mode 100644
index 0000000..6ae309c
--- /dev/null
+++ b/dev-libs/c-blosc/c-blosc-1.17.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="Blocking, shuffling and lossless compression library"
+HOMEPAGE="http://www.blosc.org/"
+SRC_URI="https://github.com/Blosc/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+
+SLOT="0/1"
+KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
+
+IUSE="cpu_flags_x86_avx2 +lz4 +snappy static-libs test zlib zstd"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	lz4? ( >=app-arch/lz4-1.7.5:= )
+	snappy? ( app-arch/snappy )
+	zlib? ( sys-libs/zlib )
+	zstd? ( app-arch/zstd )"
+DEPEND="${RDEPEND}"
+
+DOCS=( README.md README_HEADER.rst README_THREADED.rst RELEASE_NOTES.rst THOUGHTS_FOR_2.0.txt ANNOUNCE.rst )
+
+src_prepare() {
+	cmake-utils_src_prepare
+	# remove bundled libs
+	rm -rf internal-complibs || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_STATIC=$(usex static-libs)
+		-DBUILD_TESTS=$(usex test)
+		-DBUILD_BENCHMARKS=OFF
+		-DDEACTIVATE_AVX2=$(usex !cpu_flags_x86_avx2)
+		-DDEACTIVATE_LZ4=$(usex !lz4)
+		-DDEACTIVATE_SNAPPY=$(usex !snappy)
+		-DDEACTIVATE_ZLIB=$(usex !zlib)
+		-DDEACTIVATE_ZSTD=$(usex !zstd)
+		-DPREFER_EXTERNAL_LZ4=ON
+		-DPREFER_EXTERNAL_SNAPPY=ON
+		-DPREFER_EXTERNAL_ZLIB=ON
+		-DPREFER_EXTERNAL_ZSTD=ON
+	)
+	cmake-utils_src_configure
+}
-- 
cgit v1.2.3