/*
  matrix-scan a set of LEDs

  pins:

  "rows" 12 & 13 go to a 220Ω resistor, then to 2 LEDs each (positive
  / long stem side); also to a 10kΩ resistor then to 2
  phototransistors (collector / long stem side)

  also, from between the 10kΩ and the phototransistors, wire goes to
  A1 & A2

  "columns"
  14 & 15 go to 2 LEDs each (negative / short stem side)

  so that given one of 12|13 and one of 14|15, one LED is identified
 */

#include <driver/dac.h>

#define TSF_IMPLEMENTATION
#define TSF_NO_STDIO
#include "../ESP8266Audio/src/libtinysoundfont/tsf.h"

#include "../RingBuffer/src/RingBuf.h"
#include "font.h"

int currentLed = 0;

#define DEBUG 0

const size_t row_count = 5;
const size_t col_count = 5;

const int rows[row_count] = { 5, 23, 19, 18, 26 };
const int cols[col_count] = { 17, 33, 16, 21, 22 };
const int adc[row_count] = { 2, 4, 12, 27, 14 };
const int ampEnable = 32;

const int octave_shift = 2;

char pressed[row_count*col_count] = { 0 };

hw_timer_t * timer = NULL;
portMUX_TYPE timerMux = portMUX_INITIALIZER_UNLOCKED;
tsf* g_TinySoundFont = 0;
bool playing = false;

RingBuf<short, 500> buffer;

void IRAM_ATTR onTimer() {
  if (!g_TinySoundFont) return;

  portENTER_CRITICAL_ISR(&timerMux);

  short sample;
  if (buffer.pop(sample)) {
    dac_output_voltage(DAC_CHANNEL_1, sample >> 8);
  }

  portEXIT_CRITICAL_ISR(&timerMux);
}

void setup() {
  Serial.begin(115200);

  pinMode(ampEnable, OUTPUT);
  digitalWrite(ampEnable, LOW);

  dac_i2s_disable();
  dac_output_enable(DAC_CHANNEL_1);

  for (int i=0;i<row_count;++i) {
    pinMode(rows[i], OUTPUT|PULLUP);
    pinMode(adc[i], INPUT);
  }
  for (int i=0;i<col_count;++i) {
    pinMode(cols[i], OUTPUT|PULLDOWN);
  }

  currentLed = 0;
  playing = false;

  g_TinySoundFont = tsf_load_memory(SoundFont, sizeof(SoundFont));
  if (g_TinySoundFont) {
    // render at 5kHz
    tsf_set_output(g_TinySoundFont, TSF_MONO, 5000, 0);

    // pre-scaling a 40MHz clock by 4k, then calling on every 2 tick,
    // should give us 5kHz
    timer = timerBegin(0, 4000, true);
    timerAttachInterrupt(timer, &onTimer, true);
    timerAlarmWrite(timer, 2, true);
    timerAlarmEnable(timer);
  }
  else {
    Serial.println("failed to start tsf");
  }

  digitalWrite(ampEnable, HIGH);
}

void tristate(int pin) {
  pinMode(pin,OUTPUT|PULLDOWN);
  digitalWrite(pin,LOW);
  pinMode(pin,INPUT);
}

void power(int pin) {
  pinMode(pin,OUTPUT|PULLUP);
  digitalWrite(pin,HIGH);
}

void ground(int pin) {
  pinMode(pin,OUTPUT|PULLDOWN);
  digitalWrite(pin,LOW);
}

void enableLed(int led) {
  int row = (led/col_count) % row_count ;
  int col = led%col_count;

#if DEBUG & 0x02
  Serial.print("enabling ");
  Serial.print(row);
  Serial.print(" ");
  Serial.println(col);
#endif

  for (int i=0;i<row_count;++i) {
    if (i==row) { power(rows[i]); }
    else { ground(rows[i]); }
  }
  for (int i=0;i<col_count;++i) {
    if (i==col) { ground(cols[i]); }
    else { tristate(cols[i]); }
  }
}

int sense(int led) {
  int row = (led/col_count)%row_count;

  int value = analogRead(adc[row]);

#if DEBUG & 0x04
  Serial.println(value);
#endif

  return value < 500;
}

short intermediateBuffer[5000];

void loop() {
#if DEBUG & 0x01
  Serial.print("current led ");
  Serial.println(currentLed);
#endif

  enableLed(currentLed);
  unsigned long t = millis();

  int toFill = buffer.maxSize() - buffer.size();
  if (toFill > 100) {
    tsf_render_short(g_TinySoundFont, intermediateBuffer, toFill, 0);
    noInterrupts();
    for (int i=0;i<toFill;++i) {
      buffer.push(intermediateBuffer[i]);
    }
    interrupts();
  }

  while (millis() == t) {
    delayMicroseconds(100);
  }

  if (sense(currentLed)) { // currently pressed
    if (!pressed[currentLed]) { // was not pressed previously?
      Serial.print(currentLed);
      Serial.println(" proximity!");

      pressed[currentLed]=1; // mark it pressed
      if (g_TinySoundFont) {
        // start the note
        tsf_note_on(g_TinySoundFont, 0, 36 + currentLed, 1.0f);
      }
    }
  }
  // not pressed currently
  else if (pressed[currentLed]) { // was pressed previously?
    Serial.print(currentLed);
    Serial.println(" released!");

    pressed[currentLed]=0; // mark it no longer pressed
    if (g_TinySoundFont) {
      // stop the note
      tsf_note_off(g_TinySoundFont, 0, 36 + currentLed);
    }
  }

  currentLed = (currentLed+1)%(row_count*col_count);

}