From a5f0d0528a8e44944f67e935c182ab07bd885e1f Mon Sep 17 00:00:00 2001
From: dakkar <dakkar@thenautilus.net>
Date: Fri, 4 Jun 2021 18:20:22 +0100
Subject: start of karma tracking

Red is awesome, but still very "early"
---
 lib/Boha/Karma.rakumod | 79 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 79 insertions(+)
 create mode 100644 lib/Boha/Karma.rakumod

(limited to 'lib/Boha/Karma.rakumod')

diff --git a/lib/Boha/Karma.rakumod b/lib/Boha/Karma.rakumod
new file mode 100644
index 0000000..2240743
--- /dev/null
+++ b/lib/Boha/Karma.rakumod
@@ -0,0 +1,79 @@
+use v6.d;
+use IRC::Client;
+use Red:api<2>;
+use Red::AST::Function;
+
+model Boha::KarmaEvent is table<karma_event> {
+    has Int $.id is serial;
+    has DateTime $.created is column .= now;
+    has Str $.nick is column;
+    has Int $.delta is column;
+
+    method current-karma-for(::?CLASS:U: Str $nick) {
+        #`{
+        this runs:
+
+          SELECT
+            SUM("karma_event".delta) as "data_1"
+          FROM
+            "karma_event"
+          WHERE
+            "karma_event".nick = ?
+
+        }
+        self.^all.grep({ .nick eq $nick }).map(
+            {Red::AST::Function.new(:func<SUM>, :args(.delta), :returns(Int)) }
+        );
+    }
+
+    method current-karma(::?CLASS:U: Int :$top) {
+        #`{
+        this runs:
+
+          SELECT
+            "karma_event".nick as "data_1", SUM("karma_event".delta) as "data_2"
+          FROM
+            "karma_event"
+          GROUP BY
+            "karma_event".nick
+          ORDER BY
+            data_2 DESC
+
+        }
+        my $rs = self.^all
+        .map(
+            {
+                .nick,
+                Red::AST::Function.new(:func<SUM>, :args(.delta), :returns(Int))
+            }
+        )
+        #`{
+         two notes:
+
+        * $_ is a class generated my the `map`, we want its second
+          column, so that's what we say (it's usually called `data_2`,
+          but we won't depend on that)
+
+        * the `sort` works by accident! only because
+          `translate(Red::AST::Mul $_ where .left.?value == -1,
+          "order")` does not prepend `.model.^as`
+
+        }                                   
+        .sort({ -1 * .^columns[1].column})
+        ;
+        #`{
+         * there's no direct way to do a "group by"
+
+         * also, this will generate invalid SQL unless we swap the
+           `order by` and `group by` blocks in Red::Driver::CommonSQL
+
+        }
+        $rs.group = self.nick;
+        return $top ?? $rs.head($top) !! $rs;
+    }
+    
+    method new-karma(::?CLASS:U: Str $nick, Int $delta) {
+        self.^create(:$nick,:$delta);
+        return;
+    }
+}
-- 
cgit v1.2.3