From 67d30e007b8f2b2ee10529bc76460adcdf7e6c10 Mon Sep 17 00:00:00 2001
From: dakkar <dakkar@thenautilus.net>
Date: Thu, 6 May 2021 15:08:15 +0100
Subject: compact the code

---
 lib/App/XScreenSaver/DBus/Logind.pm | 153 ++++++++++++++++++++++++++++++++++++
 1 file changed, 153 insertions(+)
 create mode 100644 lib/App/XScreenSaver/DBus/Logind.pm

(limited to 'lib/App/XScreenSaver/DBus/Logind.pm')

diff --git a/lib/App/XScreenSaver/DBus/Logind.pm b/lib/App/XScreenSaver/DBus/Logind.pm
new file mode 100644
index 0000000..b8abad3
--- /dev/null
+++ b/lib/App/XScreenSaver/DBus/Logind.pm
@@ -0,0 +1,153 @@
+package App::XScreenSaver::DBus::Logind;
+use v5.20;
+use Moo;
+use experimental qw(signatures postderef);
+use curry;
+use Net::DBus;
+use IPC::Run;
+use Log::Any;
+# VERSION
+# ABSTRACT: implements the logind "inhibitor locks" and "session lock" protocols
+
+=head1 SYNOPSIS
+
+    use Net::DBus::Reactor;
+    use App::XScreenSaver::DBus::Logind;
+    my $is = App::XScreenSaver::DBus::Logind->new;
+    $is->start;
+
+    Net::DBus::Reactor->new->run;
+
+=attr C<bus>
+
+the DBus system bus
+
+=cut
+
+has bus => ( is => 'lazy', builder => sub { Net::DBus->system() } );
+
+=attr C<logind_srv>
+
+the (e)logind DBus service
+
+=cut
+
+has logind_srv => (
+    is => 'lazy',
+    builder => sub { shift->bus->get_service('org.freedesktop.login1') },
+);
+
+=attr C<logind_obj>
+
+the (e)logind DBus object
+
+=cut
+
+has logind_obj => (
+    is => 'lazy',
+    builder => sub { shift->logind_srv->get_object('/org/freedesktop/login1') },
+);
+
+=attr C<session_obj>
+
+the (e)logind session DBus object
+
+=cut
+
+has session_obj => (
+    is => 'lazy',
+    builder => sub($self) {
+        my $session_path = $self->logind_obj->GetSessionByPID($$);
+        return $self->logind_srv->get_object($session_path);
+    },
+);
+
+=attr C<inhibit_fd>
+
+the file descriptor that logind gives us when we ask for a lock; we
+close it to release the lock
+
+=cut
+
+has inhibit_fd => ( is => 'rwp' );
+
+=attr C<log>
+
+a logger
+
+=cut
+
+has log => ( is => 'lazy', builder => sub { Log::Any->get_logger } );
+
+=method C<start>
+
+starts listening to the C<PrepareForSleep> signal from (e)logind, and
+takes the lock
+
+=cut
+
+sub start($self) {
+    $self->logind_obj->connect_to_signal(
+        'PrepareForSleep',
+        $self->curry::weak::_going_to_sleep,
+    );
+    $self->session_obj->connect_to_signal(
+        'Lock',
+        $self->curry::weak::_lock,
+    );
+    $self->session_obj->connect_to_signal(
+        'Unlock',
+        $self->curry::weak::_unlock,
+    );
+    $self->_inhibit();
+    return;
+}
+
+sub _inhibit($self) {
+    return if $self->inhibit_fd;
+    $self->_set_inhibit_fd(
+        $self->logind_obj->Inhibit(
+            'sleep',
+            'xscreensaver','locking before sleep',
+            'delay',
+        )
+    );
+    $self->log->debugf('got logind inhibit fd %d',$self->inhibit_fd);
+    return;
+}
+
+sub _going_to_sleep($self,$before) {
+    if ($before) {
+        $self->log->debug('locking');
+        $self->_xscreensaver_command('-suspend');
+        $self->log->debug('locked');
+        $self->_set_inhibit_fd(undef);
+    }
+    else {
+        $self->log->debug('woken up');
+        $self->_xscreensaver_command('-deactivate');
+        $self->_inhibit();
+    }
+    return;
+}
+
+sub _lock($self) {
+    $self->_xscreensaver_command('-lock');
+}
+
+sub _unlock($self) {
+    $self->_xscreensaver_command('-deactivate');
+}
+
+sub _xscreensaver_command($self,$command) {
+    my ($out, $err);
+    IPC::Run::run(
+        ['xscreensaver-command',$command],
+        \undef, \$out, \$err,
+    );
+    $self->log->tracef('xscreensaver-command %s said <%s>',$command,$out);
+    $self->log->warnf('xscreensaver-command %s errored <%s>',$command,$err)
+        if $err;
+}
+
+1;
-- 
cgit v1.2.3