lib/Sietima/Role/SubjectTag.pm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59

package Sietima::Role::SubjectTag; 
use Moo::Role;
use Sietima::Policy;
use Types::Standard qw(Str);
use namespace::clean;
 
# VERSION 
# ABSTRACT: add a tag to messages' subjects 
 
=head1 SYNOPSIS
 
  my $sietima = Sietima->with_traits('SubjectTag')->new({
    %args,
    subject_tag => 'foo',
  });
 
=head1 DESCRIPTION
 
A L<< C<Sietima> >> list with this role applied will prepend the given
tag to every outgoing message's C<Subject:> header.
 
=attr C<subject_tag>
 
Required string. This string, enclosed by square brackets, will be
prepended to the C<Subject:> header of outgoing messages. For example,
the code in the L</synopsis> would cause an incoming message with
subject "new stuff" to be sent out with subject "[foo] new stuff".
 
If the incoming message's C<Subject:> header already contains the tag,
the header will not be modified. This prevents getting subjects like
"[foo] Re: [foo] Re: [foo] new stuff".
 
=cut
 
has subject_tag => (
    is => 'ro',
    isa => Str,
    required => 1,
);
 
=modif C<munge_mail>
 
The subject of the incoming email is modified to add the tag (unless
it's already there). The email is then processed normally.
 
=cut
 
around munge_mail => sub ($orig,$self,$mail) {
    my $tag = '['.$self->subject_tag.']';
    my $subject = $mail->header_str('Subject');
    unless ($subject =~ m{\Q$tag\E}) {
        $mail->header_str_set(
            Subject => "$tag $subject",
        );
    }
    return $self->$orig($mail);
};
 
1;