lib/Sietima/Role/WithPostAddress.pm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

package Sietima::Role::WithPostAddress; 
use Moo::Role;
use Sietima::Policy;
use Sietima::Types qw(Address AddressFromStr);
use namespace::clean;
 
# VERSION 
# ABSTRACT: role for lists with a posting address 
 
=head1 SYNOPSIS
 
  my $sietima = Sietima->with_traits('WithPostAddress')->new({
    %args,
    return_path => 'list-bounce@example.com',
    post_address => 'list@example.com',
  });
 
=head1 DESCRIPTION
 
This role adds an L<< /C<post_address> >> attribute, and exposes it
via the L<< C<list_addresses>|Sietima/list_addresses >> method.
 
On its own, this role is not very useful, but other roles (like L<<
C<ReplyTo>|Sietima::Role::ReplyTo >>) can have uses for a post
address.
 
=attr C<post_address>
 
An L<< C<Email::Address> >> object, defaults to the value of the L<<
C<return_path>|Sietima/return_path >> attribute. This is the address
that the mailing list receives messages at.
 
=cut
 
has post_address => (
    is => 'lazy',
    isa => Address,
    coerce => AddressFromStr,
);
sub _build_post_address($self) { $self->return_path }
 
around list_addresses => sub($orig,$self) {
    return +{
        $self->$orig->%*,
        post => $self->post_address,
    };
};
 
1;