lib/Feed.pm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62

package Feed; 
use Moose;
use namespace::autoclean;
use 5.016;
use MooseX::Types::URI 'Uri';
with 'MooseX::Traits';
use XML::Feed;
 
has uri => (
    is => 'ro',
    isa => Uri,
    coerce => 1,
    required => 1,
);
 
has feed => (
    is => 'ro',
    isa => 'XML::Feed',
    lazy_build => 1,
);
 
has _entries => (
    is => 'ro',
    isa => 'ArrayRef[XML::Feed::Entry]',
    traits => [ 'Array' ],
    lazy_build => 1,
    handles => {
        entries => 'elements',
        count_entries => 'count',
    },
);
 
sub process {
    my ($self) = @_;
 
    for my $entry ($self->entries) {
        $self->process_entry($entry);
    }
 
    return;
}
 
sub _build_feed {
    my ($self) = @_;
 
    return XML::Feed->parse($self->uri)
        or die XML::Feed->errstr;
}
 
sub _build__entries {
    my ($self) = @_;
 
 
    return [$self->feed->entries];
}
 
sub process_entry {
}
 
__PACKAGE__->meta->make_immutable;
 
1;