media-gfx/aoi/aoi-2.7.2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49

# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/media-gfx/aoi/aoi-2.5.ebuild,v 1.3 2009/03/14 11:56:48 maekke Exp $
 
inherit java-pkg-2 eutils
 
MY_P="aoi272"
MY_MANUAL_V="2.6"
S="${WORKDIR}/ArtOfIllusion272"
DESCRIPTION="A free, open-source 3D modelling and rendering studio."
SRC_URI="mirror://sourceforge/aoi/${MY_P}.zip
	doc? ( mirror://sourceforge/aoi/manual${MY_MANUAL_V}.zip )"
HOMEPAGE="http://aoi.sourceforge.net/index"
KEYWORDS="~amd64 ~ppc x86"
LICENSE="GPL-2"
SLOT="0"
DEPEND="app-arch/unzip"
RDEPEND=">=virtual/jre-1.5"
IUSE="doc"
 
src_install() {
	# documentation
	dodoc HISTORY README
	if use doc ; then
		mv "${WORKDIR}"/AoI\ Manual/ "${WORKDIR}"/aoi_manual
		dohtml -r "${WORKDIR}"/aoi_manual/
	fi
 
	# main app
	java-pkg_dojar ArtOfIllusion.jar
 
	# run script
	java-pkg_dolauncher aoi \
		--jar ArtOfIllusion.jar \
		--java_args -Xmx128M
 
	# plugins
	mv Plugins "${D}"/usr/share/${PN}/lib
 
	# scripts
	mv Scripts "${D}"/usr/share/${PN}/lib
 
	# icon
	mv Icons/64x64.png Icons/aoi.png
	doicon Icons/aoi.png
 
	# desktop entry
	make_desktop_entry aoi "Art of Illusion" /usr/share/pixmaps/aoi.png "Graphics"
}