net-libs/libnice/libnice-0.1.18.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
 
EAPI=7
inherit meson xdg ninja-utils multilib-minimal
 
DESCRIPTION="An implementation of the Interactice Connectivity Establishment standard (ICE)"
HOMEPAGE="https://nice.freedesktop.org/"
SRC_URI="https://nice.freedesktop.org/releases/${P}.tar.gz"
 
LICENSE="|| ( MPL-1.1 LGPL-2.1 )"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+gnutls +introspection libressl +upnp"
 
RDEPEND="
	>=dev-libs/glib-2.48:2
	introspection? ( >=dev-libs/gobject-introspection-1.30.0:= )
	gnutls? ( >=net-libs/gnutls-2.12.0:0= )
	!gnutls? (
		libressl? ( dev-libs/libressl:0= )
		!libressl? ( dev-libs/openssl:0= ) )
	upnp? ( >=net-libs/gupnp-igd-0.2.4:= )
"
DEPEND="${RDEPEND}
	dev-util/glib-utils
	>=dev-util/gtk-doc-am-1.10
	virtual/pkgconfig
"
 
multilib_src_configure() {
	local emesonargs=(
		-Dcrypto-library=$(usex gnutls gnutls openssl)
		-Dgstreamer=disabled
		$(meson_feature upnp gupnp)
	)
	if multilib_is_native_abi; then
		emesonargs+=( -Dintrospection=enabled )
	else
		emesonargs+=( -Dintrospection=disabled )
	fi
 
	meson_src_configure
}
 
multilib_src_compile() {
	eninja
}
 
multilib_src_install() {
	einstalldocs
	DESTDIR="${D}" eninja install
}