path: root/esp32/lego-piano.ino

/*
  matrix-scan a set of LEDs
 
  pins:
 
  "rows" 12 & 13 go to a 220Ω resistor, then to 2 LEDs each (positive
  / long stem side); also to a 10kΩ resistor then to 2
  phototransistors (collector / long stem side)
 
  also, from between the 10kΩ and the phototransistors, wire goes to
  A1 & A2
 
  "columns"
  14 & 15 go to 2 LEDs each (negative / short stem side)
 
  so that given one of 12|13 and one of 14|15, one LED is identified
 */
 
#include <driver/dac.h>
#include <driver/i2s.h>
 
#define TSF_IMPLEMENTATION
#define TSF_NO_STDIO
#include "../ESP8266Audio/src/libtinysoundfont/tsf.h"
 
#include "../RingBuffer/src/RingBuf.h"
#include "font.h"
 
int currentLed = 0;
 
#define DEBUG 0
 
const size_t row_count = 5;
const size_t col_count = 5;
 
const int rows[row_count] = { 5, 23, 19, 18, 26 };
const int cols[col_count] = { 17, 33, 16, 21, 22 };
const int adc[row_count] = { 2, 4, 12, 27, 14 };
const int ampEnable = 32;
 
const int octave_shift = 2;
 
const int sampleRate = 11025;
 
char pressed[row_count*col_count] = { 0 };
 
tsf* g_TinySoundFont = 0;
const i2s_port_t i2sPort = I2S_NUM_0;
 
void setup() {
  Serial.begin(115200);
 
  pinMode(ampEnable, OUTPUT);
  digitalWrite(ampEnable, LOW);
 
  dac_i2s_enable();
  dac_output_enable(DAC_CHANNEL_1);
 
  static const i2s_config_t i2s_config = {
      .mode = (i2s_mode_t)( I2S_MODE_MASTER | I2S_MODE_TX | I2S_MODE_DAC_BUILT_IN ),
      .sample_rate = sampleRate,
      .bits_per_sample = I2S_BITS_PER_SAMPLE_16BIT,
      .channel_format = I2S_CHANNEL_FMT_ALL_RIGHT,
      .intr_alloc_flags = ESP_INTR_FLAG_LEVEL1, // high interrupt priority 
      .dma_buf_count = 8,
      .dma_buf_len = 64,
      .use_apll = false
  };
 
  i2s_driver_install(i2sPort, &i2s_config, 0, NULL);
  i2s_set_dac_mode(I2S_DAC_CHANNEL_RIGHT_EN); // only dac1 
 
  for (int i=0;i<row_count;++i) {
    pinMode(rows[i], OUTPUT|PULLUP);
    pinMode(adc[i], INPUT);
  }
  for (int i=0;i<col_count;++i) {
    pinMode(cols[i], OUTPUT|PULLDOWN);
  }
 
  currentLed = 0;
 
  g_TinySoundFont = tsf_load_memory(SoundFont, sizeof(SoundFont));
  if (g_TinySoundFont) {
    // render at 5kHz 
    tsf_set_output(g_TinySoundFont, TSF_MONO, sampleRate, 0);
  }
  else {
    Serial.println("failed to start tsf");
  }
 
  digitalWrite(ampEnable, HIGH);
}
 
void tristate(int pin) {
  pinMode(pin,OUTPUT|PULLDOWN);
  digitalWrite(pin,LOW);
  pinMode(pin,INPUT);
}
 
void power(int pin) {
  pinMode(pin,OUTPUT|PULLUP);
  digitalWrite(pin,HIGH);
}
 
void ground(int pin) {
  pinMode(pin,OUTPUT|PULLDOWN);
  digitalWrite(pin,LOW);
}
 
void enableLed(int led) {
  int row = (led/col_count) % row_count ;
  int col = led%col_count;
 
#if DEBUG & 0x02
  Serial.print("enabling ");
  Serial.print(row);
  Serial.print(" ");
  Serial.println(col);
#endif
 
  for (int i=0;i<row_count;++i) {
    if (i==row) { power(rows[i]); }
    else { ground(rows[i]); }
  }
  for (int i=0;i<col_count;++i) {
    if (i==col) { ground(cols[i]); }
    else { tristate(cols[i]); }
  }
}
 
int sense(int led) {
  int row = (led/col_count)%row_count;
 
  int value = analogRead(adc[row]);
 
#if DEBUG & 0x04
  Serial.println(value);
#endif
 
  return value < 500;
}
 
const size_t bufferSize = 1000;
RingBuf<short, bufferSize> buffer;
short intermediateBuffer[bufferSize];
 
void loop() {
#if DEBUG & 0x01
  Serial.print("current led ");
  Serial.println(currentLed);
#endif
 
  enableLed(currentLed);
  unsigned long t = millis();
  size_t written=100;
  short value;
  // fill the I2S buffer 
  while (written > 0) {
    // we don't want to drop an element from the buffer if we then 
    // can't write it! so we peek at the buffer, try to write, and pop 
    // if successful 
    value=buffer[0] + 32768; // tsf produces *signed* shorts, i2s wants *unsigned* 
    i2s_write(i2sPort, &value, sizeof(value), &written, 0);
    if (written > 0) buffer.pop(value);
  }
 
  int toFill = buffer.maxSize() - buffer.size();
  if (toFill > 100) {
    tsf_render_short(g_TinySoundFont, intermediateBuffer, toFill, 0);
    for (int i=0;i<toFill;++i) {
      buffer.push(intermediateBuffer[i]);
    }
  }
 
  while (millis() == t) {
    delayMicroseconds(100);
  }
 
  if (sense(currentLed)) { // currently pressed 
    if (!pressed[currentLed]) { // was not pressed previously? 
      Serial.print(currentLed);
      Serial.println(" proximity!");
 
      pressed[currentLed]=1; // mark it pressed 
      if (g_TinySoundFont) {
        // start the note 
        tsf_note_on(g_TinySoundFont, 0, 36 + currentLed, 1.0f);
      }
    }
  }
  // not pressed currently 
  else if (pressed[currentLed]) { // was pressed previously? 
    Serial.print(currentLed);
    Serial.println(" released!");
 
    pressed[currentLed]=0; // mark it no longer pressed 
    if (g_TinySoundFont) {
      // stop the note 
      tsf_note_off(g_TinySoundFont, 0, 36 + currentLed);
    }
  }
 
  currentLed = (currentLed+1)%(row_count*col_count);
 
}