lib/GridFiller.pm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102

package GridFiller; 
use Moose;
use namespace::autoclean;
use GridFiller::Types qw(GridT WordListT );
use MooseX::Types::Moose qw(CodeRef);
use GridFiller::Status;
use GridFiller::Result::Text;
use GridFiller::Chooser::Smarter;
use Carp;
use Class::MOP;
 
with 'MooseX::Log::Log4perl';
 
has words => (
    isa => WordListT,
    required => 1,
    is => 'ro',
);
 
has grid => (
    isa => GridT,
    required => 1,
    is => 'ro',
);
 
has status => (
    isa => 'GridFiller::Status',
    is => 'ro',
    writer => '_status',
    lazy_build => 1,
);
 
sub _build_status {
    my ($self) = @_;
    return GridFiller::Status->new({
        words => $self->words,
        grid => $self->grid,
    });
}
 
has chooser => (
    isa => 'GridFiller::Chooser',
    is => 'rw',
    lazy_build => 1,
);
 
sub _build_chooser {
    my ($self) = @_;
    return GridFiller::Chooser::Smarter->new({
        status => $self->status,
    });
}
 
has result => (
    isa => 'GridFiller::Result',
    is => 'rw',
    lazy_build => 1,
);
 
sub _build_result {
    my ($self) = @_;
    return GridFiller::Result::Text->new({
        source_grid => $self->grid,
    });
}
 
sub fill {
    my ($self) = @_;
 
    my $status=$self->status;
    my $result=$self->result;
    my $chooser=$self->chooser;
 
    $status->reset;
    $result->reset;
 
    while ($status->unfilled() && $status->has_next_word()) {
        my $word = $status->get_next_word();
 
        $self->log->debug("Placing $word");
 
        my ($x,$y,$dir) = $chooser->find_place_for($word);
 
        if (! defined $x) {
            $self->log->debug("No place for $word");
            $result->mark_leftover($word);
            next;
        };
 
        $result->place_word_at($word,$x,$y,$dir);
        $status->place_word_at($word,$x,$y,$dir);
 
        if ($self->log->is_debug) {
            $self->log->debug($status->to_string);
            $self->log->debug($result->to_string);
        }
    }
 
    return;
}
 
1;