lib/Dakkar/TweetArchive.pm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88

package Dakkar::TweetArchive; 
use 5.024;
use Moo;
use experimental 'signatures';
use Net::Twitter;
use Types::Standard qw(Str InstanceOf);
use namespace::clean;
 
has [qw(consumer_key consumer_secret access_token access_token_secret)] => (
    is => 'ro',
    required => 1,
    isa => Str,
);
 
has client => (
    is => 'lazy',
    isa => InstanceOf['Net::Twitter'],
);
 
 
sub _build_client($self) {
    my $nt = Net::Twitter->new(
        traits => [
            qw/API::RESTv1_1 OAuth RetryOnError/,
            AutoCursor => {
                max_calls      => 16,
                force_cursor   => 1,
                array_accessor => 'users',
                methods        => [qw/friends followers/],
            },
        ],
        consumer_key => $self->consumer_key,
        consumer_secret => $self->consumer_secret,
    );
 
    $nt->access_token($self->access_token);
    $nt->access_token_secret($self->access_token_secret);
 
    # HACK! Net::Twitter doesn't know about C<tweet_mode>, let's teach 
    # it 
    require Net::Twitter::API;
    my $nt_class = ref($nt);
    my $meta_class = Moose::Meta::Class->initialize($nt_class);
 
    $meta_class->make_mutable;
 
    my $original = $meta_class->find_method_by_name('home_timeline');
 
    $nt_class->Net::Twitter::API::twitter_api_method(
        home_timeline => (
            description => 'override home_timeline to add tweet_mode',
            path => $original->path,
            method => $original->method,
            params => [
                @{ $original->params },
                'tweet_mode',
            ],
            booleans => $original->booleans,
            required  => $original->required,
            returns   => $original->returns,
        ),
    );
 
    $meta_class->make_immutable;
 
    return $nt;
}
 
sub home_timeline($self,$since_id) {
    return $self->client->home_timeline({
        include_entities => 1,
        trim_user => 0,
        exclude_replies => 0,
        ( $since_id ? ( since_id => $since_id ) : () ),
        count => 200,
        tweet_mode => 'extended',
    });
}
 
sub friends($self) {
    return $self->client->friends({count=>200});
}
 
sub followers($self) {
    return $self->client->followers({count=>200});
}
 
1;