lib/File/Cache/Parsed.pm


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110

package File::Cache::Parsed; 
use strict;
use warnings;
use List::Util qw(first);
use List::MoreUtils qw(firstidx);
use Cwd 'abs_path';
use Path::Class;
use Carp;
 
sub new {
    my ($class,%opts)=@_;
 
    return bless {
        parsers=>[],
        writers=>[],
        cache=>{},
        follow=>$opts{follow},
    }=>$class;
}
 
sub add_parser {
    my ($self,$rx,$parser)=@_;
 
    my $old_parser=first {$_->[0] eq $rx} @{$self->{parsers}};
    if ($old_parser) {
        $old_parser->[1]=$parser;
    }
    else {
        push @{$self->{parsers}},[$rx,$parser];
    }
    return;
}
 
sub add_writer {
    my ($self,$rx,$writer)=@_;
 
    my $old_writer=first {$_->[0] eq $rx} @{$self->{writers}};
    if ($old_writer) {
        $old_writer->[1]=$writer;
    }
    else {
        push @{$self->{writers}},[$rx,$writer];
    }
    return;
}
 
sub del_parser {
    my ($self,$rx)=@_;
 
    my $i=firstidx {$_->[0] eq $rx} @{$self->{parsers}};
    return if $i<0;
 
    splice @{$self->{parsers}},$i,1;
 
    $self->invalidate($rx);
 
    return;
}
 
sub get {
    my ($self,$filename)=@_;
 
    if ($self->{follow}) {
        $filename=abs_path($filename);
    }
 
    return $self->{cache}{$filename} if exists $self->{cache}{$filename};
 
    my $contents=file($filename)->slurp;
 
    my $pp=first {$filename =~ m{$_->[0]}} @{$self->{parsers}};
    if ($pp) {
        return $self->{cache}{$filename}=$pp->[1]->($filename,$contents);
    }
    else {
        return $self->{cache}{$filename}=$contents;
    }
}
 
sub put {
    my ($self,$filename,$contents)=@_;
 
    my $ww=first {$filename =~ m{$_->[0]}} @{$self->{writers}};
    if ($ww) {
        $self->{cache}{$filename}=$contents;
        return $ww->[1]->($filename,$contents);
    }
    elsif (!ref($contents)) {
        $self->{cache}{$filename}=$contents;
        return print {file($filename)->openw} $contents;
    }
    else {
        croak "'$contents' is not a scalar, and no writer defined for the name '$filename'";
    }
}
 
sub invalidate {
    my ($self,$rx)=@_;
 
    my $count=0;
    for my $filename (keys %{$self->{cache}}) {
        if ($filename =~ m{$rx}) {
            delete $self->{cache}{$filename};
            ++$count;
        }
    }
    return $count;
}
 
1;